home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib09.dsk / DISK DUMP.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  47 lines
  1. 1  REM  *******************************
  2. 2  REM  *     DISK DUMP               *
  3. 3  REM  *   BY DAVID KRATHWOHL        *
  4. 4  REM  *   COPYRIGHT (C) 1982        *
  5. 5  REM  *   BY MICRO-SPARC INC        *
  6. 6  REM  *   LINCOLN, MA. 01773        *
  7. 7  REM  *   ALL RIGHTS RESERVED       *
  8. 8  REM  *******************************
  9. 10  HOME : VTAB 10: HTAB 10: INVERSE : PRINT " READING DIRECTORY ": NORMAL 
  10. 20  GOSUB 360: REM  POKE IOB INTO MEMORY
  11. 30  FOR J = 15 TO 0  STEP  -1
  12. 40  POKE 783,J: REM  STEPS THROUGH SECTORS
  13. 50  CALL 768
  14. 60 SB = SB +1
  15. 70  POKE 787,32 +SB
  16. 80  NEXT J
  17. 90  DIM CT$(150)
  18. 100 DB = 8192:CO = 0:EN = 0:TE = 0
  19. 110  FOR I = DB +13 +CO *256 TO DB +(CO +1) *256  STEP 35
  20. 120 DE =  PEEK(I -2): IF DE = 255  THEN 140: REM  DELETED FILE
  21. 130 TE =  PEEK(I): IF TE = 130  OR TE = 2  THEN 170: REM  APPLESOFT FILE
  22. 140 TE = 0: NEXT I
  23. 150 CO = CO +1: IF CO = 15  THEN 220
  24. 160  GOTO 110
  25. 170  FOR J = 1 TO 30:CH =  PEEK(I +J):CT$(EN) = CT$(EN) + CHR$(CH): NEXT J
  26. 180 EN = EN +1
  27. 190 TE = 0: NEXT I
  28. 200 CO = CO +1: IF CO = 15  THEN 220
  29. 210  GOTO 110
  30. 220 D$ =  CHR$(4)
  31. 230  PRINT D$"OPEN DUMPER"
  32. 240  PRINT D$"DELETE DUMPER"
  33. 250  PRINT D$"OPEN DUMPER"
  34. 260  PRINT D$"WRITE DUMPER"
  35. 270  FOR K = 0 TO EN -1
  36. 280  PRINT "PRINT "; CHR$(34);CT$(K); CHR$(34)
  37. 290  PRINT "LOAD ";CT$(K)
  38. 300  PRINT "LIST"
  39. 305  PRINT "PRINT CHR$(140)": REM  FORM FEED ON MX-80
  40. 310  NEXT K
  41. 320  PRINT "DELETE DUMPER"
  42. 330  PRINT D$"CLOSE DUMPER"
  43. 340  PRINT D$"EXEC DUMPER"
  44. 350  END 
  45. 360  FOR I = 0 TO 30: READ ML: POKE 768 +I,ML: NEXT I
  46. 370  DATA     169,3,160,10,32,217,3,96,0,0,1,96,1,0,17,0,27,3,0,32,0,0,1,0,0,96,1,0,1,239,216 
  47. 380  RETURN